Big Sky

2008/01/31

意外と知られていないvimのtips(svn commitした時にcommit対象のファイルをコメント出力する)

昨日の記事「Publish::Jaikuをでっちあげた」でご紹介したソースコードは、最終的にはCodeReposにcommitする事にしました。
で、その際CodeReposのトップページで読んだコミットルール
Commit messege rule


svn ci -m "lang/LanguageName/BigProjectName: Commit messege."

svn ci -m "lang/LanguageName/misc/ScriptName: Commit messege."

svn ci -m "dotfiles/SoftwareName/Username-Filename: Commit messege."

を守ってcommit時にファイル名を一覧しました。
で、悩んだのが複数のファイルをcommitする場合。
色々な人のcommit logを見てたら、皆さん


lang/LanguageName/BigProjectName,

lang/LanguageName/misc/ScriptName,

dotfiles/SoftwareName/Username-Filename:

  Added.

といった書き方をされていました。
でもこれってU*NIXなら"pwd"して、コピれば簡単ですが、Windowsの場合は"¥"になったり、部分的にチェックアウトしている場合には"pwd"で取得出来るものはなかったりと不便だったりします。
で、なんか楽出来ないかなと思いまして今回はこのcommit対象ファイル一覧を"svn commit"時のコメントとして出力してくれるvimscriptをご紹介します。
※というか、さっき作りました。

仕組みとしては、"svn info"を実行すると出力される


URL : http://host/root/path/to/dir

Repository Root : http://host/root

という部分の2行の差、「path/to/dir」を取得し、svn commit実行時にエディタに表示されている




--This line, and those below, will be ignored--



A    docs

A    docs/file1.txt

A    docs/file2.txt

A    docs/file3.txt

のファイル名部分の先頭に上記フォルダ「path/to/dir」を付与し


path/to/dir/docs,

path/to/dir/docs/file1.txt,

path/to/dir/docs/file2.txt,

path/to/dir/docs/file3.txt:

というコメントを生成します。
あとはこれをFileTypeがsvnの場合に動作するようにautocmdを作ればsvn commit時に


path/to/dir/docs,

path/to/dir/docs/file1.txt,

path/to/dir/docs/file2.txt,

path/to/dir/docs/file3.txt:

 

--This line, and those below, will be ignored--



A    docs

A    docs/file1.txt

A    docs/file2.txt

A    docs/file3.txt

という画面が現れます。カーソルも":"の次の行に移動しますので、そこからコメントを書くと事が出来ます。
ツールは横着から生まれる物ですね!

vimscriptのコードは以下の通り


"=============================================================================

" File: svn_file_comment.vim

" Author: Yasuhiro Matsumoto <mattn.jp@gmail.com>

" Last Change: Fri, 12 Oct 2007

" Version: 0.1

"-----------------------------------------------------------------------------

" when editing comment for 'svn commit',

"  it append svn comment like following

"

"   root/path/to/dir/docs,

"   root/path/to/dir/docs/file1.txt,

"   root/path/to/dir/docs/file2.txt,

"   root/path/to/dir/docs/file3.txt:

"   <= cursor

"   --This line, and those below, will be ignored--

"   A    docs

"   A    docs/file1.txt    

"   A    docs/file2.txt    

"   A    docs/file3.txt    

"-----------------------------------------------------------------------------



function! AppendCommitFiles()

  let lstart = search("^--", "n")

  let lend = line("$")

  if line(".") > 1 || lstart != 2

    return

  endif

  let oldlang=$LANG

  let $LANG="C"

  let lines=system("svn info")

  let $LANG=oldlang

  let url=substitute(lines, '.*\nURL: \([^\x0A]*\).*', '\1', '')

  let root=substitute(lines, '.*\nRepository Root: \([^\x0A]*\).*', '\1', '')

  if match(url, root) != 0

    return

  endif

  let basedir=substitute(strpart(url, strlen(root)), '^\/*', '', '')

  let lcur = lstart

  let lines = ""

  let mx = '^\s*[A-Z]\s\+\([^$]\+\)$'

  while lcur <= lend

    let line = getline(lcur)

    if line =~ mx

      let lines .= basedir."/".substitute(line, mx, '\1', '')."\<NL>"

    endif

    let lcur = lcur + 1

  endwhile

  let lines = substitute(lines, '\n.', ',&', 'g')

  let lines = substitute(lines, '\n$', ':&', '')

  call cursor(0)

  let value = getreg("a")

  let type = getregtype("a")

  call setreg("a", lines, "c")

  execute 'normal! "ap'

  call setreg("a", value, type)

  silent! /^$

endfunction

autocmd FileType svn call AppendCommitFiles()

例によって、このソースもCodeReposのコノ辺に置く予定です。

追記
ちょこっと修正

Posted at by mattn

意外と知られていないvimのtips(vimでオブジェクト継承)

vimscriptの発祥から考えると、vimで扱えるオブジェクトはあくまで数値、文字列レベルの物でしかないと思われがちですが、Dictionaryとfunction()を使えば、それとなく継承ぽい事が出来ます。
まぁ、javascriptに近い言語仕様というのもありますからね。
以下のコードでは、簡単なクラスとオブジェクトを定義しています。


function! Class_Prototype() dict

  return self

endfunction



function! Class_Override(...) dict

  if a:0 == 0|throw "Invalid Parameter"|endif

  let class = copy(self)

  let class.__NAME__ = a:1

  if type(a:2) == type(class.New)

    let class.New = a:2

  else

    let class.New = self.New

  endif

  let class.Super = self

  return class

endfunction



function! Class_New(...) dict

  let instance = copy(self)

  call remove(instance, "New")

  call remove(instance, "Override")

  let instance.Super = self

  return instance

endfunction



function! Class_ToString() dict

    return self.__NAME__

endfunction



let Object = {

 \ "__NAME__" : "Object",

 \ "Prototype": function("Class_Prototype"),

 \ "Override": function("Class_Override"),

 \ "Super": {},

 \ "New": function("Class_New"),

 \ "ToString": function("Class_ToString")}

この状態で


if exists("object")|unlet object|endif

let object = Object.New()

echo object.ToString() . ":..."

とすると


Object:...

と表示されます。

ここで


function! Human_Sing() dict

  return self.perfix . "は" . self.name . "。" . self.title

endfunction

function! Human_New(...) dict

  let instance = copy(self)

  let instance.perfix = a:1

  let instance.name = a:2

  let instance.title = a:3

  let instance.Sing = function("Human_Sing")

  return instance

endfunction

let Human = Object.Override("Human", function("Human_New"))

とすると、Objectクラスを継承するHumanクラスを定義する事が出来ます。
さらにこの状態で


if exists("human")|unlet human|endif

let human = Human.New("私", "人間", "一般人")

echo human.ToString() . ":" . human.Sing()

とすると


Human:私は人間。一般人

と表示されます。
つまり、Newメソッドをオーバーライドし、Singメソッドを追加した事になります。ToStringメソッドはObjectクラスのメソッドとなります。
vimscriptはJavascriptのように、メンバを動的に生成出来ますので


function! Gian_Boxing(who) dict

  return a:who . "のくせに生意気だぞ!!!"

endfunction

let Gian = Human.Override("Gian", {})

let Gian.Boxing = function("Gian_Boxing")

if exists("gian")|unlet gian|endif

let gian = Gian.New("俺", "ジャイアン", "ガキ大将")

echo gian.ToString() . ":" . gian.Sing()

echo gian.Boxing("のび太")

とすると


Gian:俺はジャイアン。ガキ大将

のび太のくせに生意気だぞ!!!

とジャイアンが生成出来ます。
意外とやれるもんですね。

ただ、せっかくローカルスコープ、スクリプトスコープ、グローバルスコープ等、名前空間は既にしっかり存在してるんだから、もう少し他のオブジェクト指向言語(JavaやJavaString、C#やVB.NET)のように既定メソッドとかデフォルトコンストラクタみたいな概念が欲しいなぁ...
あと関数名は先頭大文字強制ってのは痛い。
ま、その辺はまた今度...

mattn the vimscripter

Posted at by mattn

vimからWordPressにブログを投稿する(ちょっと改造してBXRにも対応かも)

vim.orgを物色してたら

Vimpress : Manage wordpress blog posts from Vim

というvimからWordPressに記事投稿出来るスクリプトを発見。まぁ、だいたい中身も想像出来ましたが物は試しと随分前にアカウントを取ってて全然使ってないWordPress.comのサイトにポストしてみました。で、予定通りマルチバイトで文字化けしたので、改造してみました。
基本的な修正は文字コード周りですが、カテゴリの取得方法をMTからmetaWeblogに変えて、BXR: Blosxom XML-RPC Interfaceにも対応してみました。
ただここへのポストはまだ試してないです。苦笑
オリジナルがGPL2ライセンスでしたので、今回はpatchで配布します。