Big Sky

2008/01/31

意外と知られていないvimのtips(Mac OSXでもExploreから拡張子に応じたアプリケーションを起動)

vimにはexplore.vimというスクリプト(現在はnetrw.vimに統合)が付属しており


# vim /usr/include

等と実行すると、vimがファイラとして起動します。同様にコマンドラインから


:e /usr/include

と実行しても同じ結果になります。コマンド単体としてもExploreとして起動出来ます。
このExplore実は結構よく出来ていて、以前ご紹介した「男は黙ってvimでリモート編集」の応用として


:e ftp://ftp.vim.org/pub/vim/

Enter username: anonymous

Enter Password: *********

でフォルダ閲覧出来ます。(*********はanonymous)


" ============================================================================

" Netrw Directory Listing                                        (netrw v109)

"   ftp://ftp.vim.org/pub/vim/

"   Sorted by      name

"   Sort sequence: [\/]$,\.h$,\.c$,\.cpp$,\.[a-np-z]$,*,\.info$,\.swp$,\.o$\.obj

"   Quick Help: <F1>:help  -:go up dir  D:delete  R:rename  s:sort-by  x:exec

" ============================================================================

../

./

MIRRORS

README

amiga

atari

be

beanie.gif

doc

extra

faq.html

farsi

green_ball.gif

index.html

ftp://ftp.vim.org/pub/vim/ [RO]                                       1,1     2%

また、Exploreではファイル名にカーソルを合わせて「x」をタイプすると拡張子に合わせてアプリケーションが起動します。
例えばWindowsでファイル名が「勤務表.xls」であればExcelが起動します。

この「x」で外部アプリケーションが起動する機能、現状はWindows、GNOME、KDEをサポートしています。
ちょっとソースを見たところ、netrw.vimには元となったexplore.vimに昔々に私が入れ込んだ「explFileHandler」が別名「netrwFileHandlers」として取り込まれてました。
ただ、「netrwFileHandlers」は私が元々想定していた単一のユーザ関数ではなく「netrwFileHandlers#Invoke」という関数でファイル種別毎に分別され、ファイル種別毎のスクリプト関数が実装されていました。
これをグローバルで宣言すれば自分独自の設定も出来るという仕組みです。


let g:netrw_browsex_viewer='-'

" エディタであるvimから秀丸起動して、何やってんだか...

function! NFH_txt(file)

    " netrwFileHandlers.vimの不具合回避？

    let f = substitute(a:file, '^\([A-Z]\)COLON', '\1:', '')



    exe "silent !start c:/progra~1/hidemaru/hidemaru.exe \"".f."\""

    return 1

endfunction

こんな感じのユーザ関数を作れば例えば.plや.shでperlやbashを起動したりする事も出来ます。
コード内にある「netrw_browsex_viewer」ですが、"-"に設定すると上記のようなユーザ/スクリプト関数を呼び出す機能として動作しますが、実行可能なコマンドを設定するとそのまま起動してくれるようにもなっています。
これを使用すれば、現状Windows、GNOME、KDEしかサポートしていないnetrw.vimでも、Mac OS Xに対応する事が出来ます。
私はMac OS Xを持っていないので確認出来ませんが、MacWiki - OSXの固有コマンドを見ると、Mac OS Xではコマンドラインからファイルを開く「open」コマンドがあるらしいので


let g:netrw_browsex_viewer = 'open'

とvimrcに設定しておけば、Exploreから「x」をタイプする事でファイル種別に応じたアプリケーションが起動出来るかと思います。
※どなたか動作報告頂ければ、オフィシャルにマージして貰えるかもしれません。

その他、netrw.vimが使用するftp/sshのコマンドライン等の設定は


:NetrwSettings

とすれば、設定画面が表示されますので、色々カスタマイズして見ると面白いかもしれませんね。

mattn the vim explorer

Posted at by mattn

意外と知られていないvimのtips(vimでオブジェクト継承)

vimscriptの発祥から考えると、vimで扱えるオブジェクトはあくまで数値、文字列レベルの物でしかないと思われがちですが、Dictionaryとfunction()を使えば、それとなく継承ぽい事が出来ます。
まぁ、javascriptに近い言語仕様というのもありますからね。
以下のコードでは、簡単なクラスとオブジェクトを定義しています。


function! Class_Prototype() dict

  return self

endfunction



function! Class_Override(...) dict

  if a:0 == 0|throw "Invalid Parameter"|endif

  let class = copy(self)

  let class.__NAME__ = a:1

  if type(a:2) == type(class.New)

    let class.New = a:2

  else

    let class.New = self.New

  endif

  let class.Super = self

  return class

endfunction



function! Class_New(...) dict

  let instance = copy(self)

  call remove(instance, "New")

  call remove(instance, "Override")

  let instance.Super = self

  return instance

endfunction



function! Class_ToString() dict

    return self.__NAME__

endfunction



let Object = {

 \ "__NAME__" : "Object",

 \ "Prototype": function("Class_Prototype"),

 \ "Override": function("Class_Override"),

 \ "Super": {},

 \ "New": function("Class_New"),

 \ "ToString": function("Class_ToString")}

この状態で


if exists("object")|unlet object|endif

let object = Object.New()

echo object.ToString() . ":..."

とすると


Object:...

と表示されます。

ここで


function! Human_Sing() dict

  return self.perfix . "は" . self.name . "。" . self.title

endfunction

function! Human_New(...) dict

  let instance = copy(self)

  let instance.perfix = a:1

  let instance.name = a:2

  let instance.title = a:3

  let instance.Sing = function("Human_Sing")

  return instance

endfunction

let Human = Object.Override("Human", function("Human_New"))

とすると、Objectクラスを継承するHumanクラスを定義する事が出来ます。
さらにこの状態で


if exists("human")|unlet human|endif

let human = Human.New("私", "人間", "一般人")

echo human.ToString() . ":" . human.Sing()

とすると


Human:私は人間。一般人

と表示されます。
つまり、Newメソッドをオーバーライドし、Singメソッドを追加した事になります。ToStringメソッドはObjectクラスのメソッドとなります。
vimscriptはJavascriptのように、メンバを動的に生成出来ますので


function! Gian_Boxing(who) dict

  return a:who . "のくせに生意気だぞ!!!"

endfunction

let Gian = Human.Override("Gian", {})

let Gian.Boxing = function("Gian_Boxing")

if exists("gian")|unlet gian|endif

let gian = Gian.New("俺", "ジャイアン", "ガキ大将")

echo gian.ToString() . ":" . gian.Sing()

echo gian.Boxing("のび太")

とすると


Gian:俺はジャイアン。ガキ大将

のび太のくせに生意気だぞ!!!

とジャイアンが生成出来ます。
意外とやれるもんですね。

ただ、せっかくローカルスコープ、スクリプトスコープ、グローバルスコープ等、名前空間は既にしっかり存在してるんだから、もう少し他のオブジェクト指向言語(JavaやJavaString、C#やVB.NET)のように既定メソッドとかデフォルトコンストラクタみたいな概念が欲しいなぁ...
あと関数名は先頭大文字強制ってのは痛い。
ま、その辺はまた今度...

mattn the vimscripter

Posted at by mattn

vimからWordPressにブログを投稿する(ちょっと改造してBXRにも対応かも)

vim.orgを物色してたら

Vimpress : Manage wordpress blog posts from Vim

というvimからWordPressに記事投稿出来るスクリプトを発見。まぁ、だいたい中身も想像出来ましたが物は試しと随分前にアカウントを取ってて全然使ってないWordPress.comのサイトにポストしてみました。で、予定通りマルチバイトで文字化けしたので、改造してみました。
基本的な修正は文字コード周りですが、カテゴリの取得方法をMTからmetaWeblogに変えて、BXR: Blosxom XML-RPC Interfaceにも対応してみました。
ただここへのポストはまだ試してないです。苦笑
オリジナルがGPL2ライセンスでしたので、今回はpatchで配布します。