私もしかり、このブログにおいても全てvimで編集しています。
ソースコードは上記リンクに記した通り「:TOhtml」を使い、その他はほぼ全て打ち込んでいます。ただ別のサイトにある記事やリンクを引用する場合、少し手間が発生します。例えば
<a href="http://example.com">サンプル</a>
とタイプする場合、ブラウザのアドレスバーからURLを、さらにブックマーク画面を出してタイトルをコピーして上の様な記述に置き換えるとなるとキーボードだけで操作出来なかったりして少し煩わしい感じがしますね。オーサリングツールやmarkdown等で楽する事も出来ますがちょっとした更新で、しかもvimが使いたいなんて場合もありますよね。また、ブラウザは起動していないけどURLならもう知ってるなんて場合、タイトル抜き出すのが大変なんて思っていませんか？
今日は私が使っているvimスクリプトを紹介してみます。
まずソース
let g:Anchorize_Format = '<a href="%s" class="external" target="_blank">%s</a>'
function! Anchorize_TITLE(url)
silent! split _FETCHTITLE_
silent! exec "0r!curl -s ".a:url
if executable('nkf')
if &enc == 'utf-8'
silent! %!nkf -X8
elseif &enc == 'cp932'
silent! %!nkf -Xs
endif
endif
silent! %join!
silent! %g/^\s*$/d _
silent! %s/^.\{-}<title[^>]*>\([^<]\+\)<\/title>.*/\1/i
let ret = getline('.')
silent! bw!
if exists('Anchorize_Format')
let format = Anchorize_Format
else
let format = '<a href="%s">%s</a>'
endif
return printf(format, a:url, ret)
endfunction
function! Anchorize_URL(v)
let url = input('URL:')
if len(url)
if exists('Anchorize_Format')
let format = Anchorize_Format
else
let format = '<a href="%s">%s</a>'
endif
if a:v
silent! normal! gvs
let word = getreg('"')
exec "normal! a".printf(format, url, word)
else
let word = expand('<cword>')
exec "normal! ciw".printf(format, url, word)
endif
endif
endfunction
nnoremap <leader>,u :call Anchorize_URL(0)<cr>
vnoremap <leader>,u :<c-w>call Anchorize_URL(1)<cr>
vnoremap <leader>,U s<c-r>=Anchorize_TITLE(getreg('"'))<cr><esc>
これをanchorize.vimとかでpluginディレクトリに放り込むとインストール完了。使い方は、まず
今日もGoogleで検索
の「Google」という部分を「http://www.google.co.jp/」へのリンクにしたい場合には「Google」の部分までカーソルを移動して
<leader>,u
「<leader>」は何も設定していなければ「¥」になっているかと思います。とタイプすると
URL:
というプロンプトが出るのでここに
URL:http://www.google.co.jp/
とタイプしてENTERを押すと
今日も<a href="http://www.google.co.jp/">Google</a>で検索
と変換されます。また空白を含んだ、例えば「Google Search」の様な場合「Google Search」をビジュアル選択して「<leader>,u」とすれば同じ動作になります。さらに例えば
今日もhttp://b.hatena.ne.jp/でホットエントリ
というテキストのURL部分をビジュアル選択し、今度は
<leader>,U
「U」は大文字とタイプすると
今日も<a href="http://b.hatena.ne.jp/">はてなブックマーク - ソーシャルブックマーク</a>でホットエントリ
と変換してくれます。急いでネタ記事をアップしたいvimmerには重宝するのではないかと思います。なお、動作にはnkfというフィルタコマンドが必要です。Windowsであれば「nkf win32」あたりで検索すればヒットするかと思います。ちなみに、vimrc等でAnchorize_Formatという変数を
let g:Anchorize_Format = '<a href="%s" class="external" target="_blank">%s</a>'
等といった感じに編集する事も出来るので、class属性を常に付けたい人にも使えるかと思います。元々公開するつもりも無かったスクリプトなので、拡張性ありませんがよろしければどうぞ。
